ArmAScript Examples

Milosan on the BIS forums wanted an addAction controlled hostage script.  Here’s how I did it:

It used a preset list of units, addAction, a script and a trigger.

Preset list of units set in init.sqf or somewhere similar, in this demo it’s done in the init field of the player:

POWS = [p1,p2,p3,p4]

p1 through p4 are captured civilians in a storage container. They are grouped, but since we’re using the array we just declared they wouldn’t have to be. The group leader has the following addAction in his init field:

this addAction ["Rescue POWs","rescuePows.sqf",[POWS],1,false,true,"","(_target distance _this) < 3"];

That will present the player with a “Rescue POWs” action prompt if they are within 3m of the group leader. Upon selecting that action this script will run:

_per = _this select 0;  // Person who had the addAction
_ldr = _this select 1;  // Person who used the addAction
_act = _this select 2;  // ID of the addAction

// Group given in the arguments section (ie: [POWS]
_grp = _this select 3 select 0;

// Remove the rescue option
_per removeAction _act;

// Join preselected units (POWS) to callers group, silently.
{[_x] joinSilent _ldr} forEach _grp;

The units will join the player’s group, following him and following his orders as normal units would. In this demo the player is to turn around and tell the POWs to board the waiting Mi-17 (named rescue1) that just landed. This will mark them as “rescued” according to a trigger once they are onboard the helo. The condition of the trigger is such that if some should die, the rest can still be saved.

Trigger Condition =

{alive _x && (_x in rescue1)} count POWS == {alive _x} count POWS

Trigger onAct =

hint "POWs rescued!";{[_x] joinSilent grpNull} forEach POWS

This will remove the POWs from the player’s group. You might want to mark an objective complete at this point perhaps.

An interactive demo mission of this technique is available.